EAPI=7

PYTHON_COMPAT=( python3_{9..11} )
inherit autotools prefix python-any-r1 xdg

DESCRIPTION="Fork of Chocolatey Doom with visual crispness enhancements"
HOMEPAGE="https://github.com/fabiangreffrath/crispy-doom"
SRC_URI="https://github.com/fabiangreffrath/crispy-doom/archive/refs/tags/crispy-doom-${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc libsamplerate +midi png vorbis"

DEPEND="
    media-libs/libsdl2[video]
    media-libs/sdl2-mixer[midi?,vorbis?]
    media-libs/sdl2-net
    media-sound/fluidsynth
    sys-libs/zlib
    libsamplerate? ( media-libs/libsamplerate )
    png? ( media-libs/libpng:= )
"
RDEPEND="${DEPEND}"
BDEPEND=""

S="${WORKDIR}/${PN}-${P}"

DOCS=(
	"AUTHORS"
	"ChangeLog"
	"NEWS.md"
	"NOT-BUGS.md"
	"PHILOSOPHY.md"
	"README.md"
	"README.Music.md"
	"README.Strife.md"
)

src_prepare() {
	default

	hprefixify src/d_iwad.c

	eautoreconf
}


src_configure() {
	econf \
		--enable-bash-completion \
		$(use_enable doc) \
		--disable-fonts \
		--disable-icons \
		$(use_with libsamplerate) \
		$(use_with png libpng)
}

src_install() {
	emake DESTDIR="${D}" install

	# Remove redundant documentation files
	rm -r "${ED}/usr/share/doc/"* || die

	einstalldocs
}