diff --git a/app-emulation/86Box/86Box-4.2.2_rc1.ebuild b/app-emulation/86Box/86Box-4.2.2_rc1.ebuild
new file mode 100644
index 0000000..2141f71
--- /dev/null
+++ b/app-emulation/86Box/86Box-4.2.2_rc1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://heap.otl-hga.net/file/7KZ2QjrPYEqaE0Py/zT3FwGpRxiI9OxXw/86Box-4.2.2_rc1.tar.gz?dl=1 -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+#KEYWORDS="~amd64"
+IUSE="experimental +fluidsynth +munt new-dynarec +openal +qt6 +threads vde"
+
+DEPEND="
+	app-emulation/faudio
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt6? ( x11-libs/libXi )
+	vde? ( net-misc/vde )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt6? (
+		dev-qt/qtbase:6[gui,network,opengl,widgets]
+		dev-qt/qttranslations:6
+		kde-frameworks/extra-cmake-modules
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# LTO needs to be filtered
+	# See https://bugs.gentoo.org/854507
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDYNAREC="ON"
+		-DMUNT_EXTERNAL="$(usex munt)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DRTMIDI="ON"
+		-DQT="$(usex qt6)"
+		-DRELEASE="ON"
+		$(usex qt6 '-DUSE_QT6=ON' '')
+		-DHAS_VDE="$(usex vde "${EPREFIX}/usr/$(get_libdir)/libvdeplug.so" "HAS_VDE-NOTFOUND")"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}
diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
new file mode 100644
index 0000000..516faca
--- /dev/null
+++ b/app-emulation/86Box/Manifest
@@ -0,0 +1,2 @@
+DIST 86Box-4.2.2_rc1.tar.gz 5810798 BLAKE2B 77ecfb57dd552fc6c903562469663f8cb6055fba815619459477646669da9b76dcecd2304c52aaa0f795954a27d296555d66cfb0f0a456d69604b05ebd2bdcf6 SHA512 f09703c425b51eed9afc07c7a6481e2172630abd5f994e64b0a373a2a4027922fd25bc11647bc0d23585558885e64726ae09c3332d5e3a16bb103272e78fb3fe
+EBUILD 86Box-4.2.2_rc1.ebuild 1815 BLAKE2B 094381848b84c3f69b2e9a7e2cbd9d4520337c51f59d2ac311a456618d67056047b860bc421b6baa33c26ae9b8d4996c31dda069cf52c1bc6374f8c41d80aab7 SHA512 526e7a0e727d5b53cffaf6b9187a542ad5395a85a4292209c702b4dd100c36b7d7e846bac445268273315349117ffd4708212198c73ae5614f21055dacac8a23